::This file belongs to the TOIL package |Ten plik nale/zy do pakietu TOIL
::This package is public domain         |Pakiet stanowi dobro powszechne
::For more info see `0TOILENG.LIC'      |Wi/ecej informacji w ,,0TOILPOL.LIC''
::============================================================================
@echo off
if "%1"=="" goto USAGE
set TOILPATH=.;..!;c:/toil
::
echo %1>> _clp_.tmp
:: room for default parameters
shift 
if "%1"=="" goto ENDLOOP
:LOOP
echo %1>> _clp_.tmp
shift 
if "%1"=="" goto ENDLOOP
goto LOOP
:ENDLOOP 
::
gawk -ftoila.awk -vCLP=_clp_.tmp
if errorlevel==1 goto HALT1
:: toiltmp1.bat: gawk -ftoilb.awk
::           generates %1.mf
call toiltmp1.bat
if errorlevel==1 goto HALT2
:: toiltmp2.bat: mf386 &plain APPROPRIATE_OPTIONS MF_FILE
call toiltmp2.bat
if errorlevel==1 goto HALT3
:: toiltmp3.bat: gawk -ftoilc.awk MF_FILE.LOG
::           extracts information from MF_FILE.LOG
call toiltmp3.bat
if errorlevel==1 goto HALT4
goto END0
:: 
:: ERROR MESSAGES:
:HALT1
echo ! STAGE 1: something went wrong.
goto END0
:HALT2
echo ! STAGE 2: something went wrong.
goto END0
:HALT3
echo ! STAGE 3: something went wrong (see METAFONT's LOG file).
goto END1
:HALT4
echo ! STAGE 4: something went wrong.
goto END0
:: END OF ERROR MESSAGES
:: 
:USAGE
echo USAGE:
echo      A2T font_name [additional_parameters]
echo   Additional parameters can have the following form:
echo     -L[ ]external_ligature_file_name
echo     -E[ ]external_encoding_file_name
echo     -M[ ]METAFONT_file_name
echo     -N[ ]resulting_encoding_file_name
echo     -X[ ]x_scaling
echo     -I[ ]italic_angle
echo     -G[ ]zero_or_one
echo   where [ ] optional space; for details see file 0TOILENG.INF.
echo WYWO/LANIE:
echo      A2T nazwa_fontu [parametry_dodatkowe]
echo   Parametry dodatkowe mog/a mie/c nast/epuj/ac/a posta/c:
echo     -L[ ]nazwa_pliku_definiuj/acego_ligatury
echo     -E[ ]nazwa_pliku_definiuj/acego_uk/lad_znak/ow
echo     -M[ ]nazwa_tymczasowego_pliku_METAFONTowego
echo     -N[ ]nazwa_wynikowego_pliku_z_uk/ladem_znak/ow
echo     -X[ ]wsp/o/lczynnik_przeskalowania_poziomego_fontu
echo     -I[ ]k/at_pochylenia_fontu
echo     -G[ ]zero_lub_jeden
echo   gdzie [ ] oznacza opcjonalny odst/ep; szczeg/o/ly -- p. 0TOILENG.INF;
echo   do instalowania font/ow z polskimi znakami zalecane jest u/zycie A2TQX.BAT.
:END0
:: toiltmp4.bat: clean MF and LOG files, if required and if MF-ing was OK
if exist toiltmp4.bat call toiltmp4.bat
:END1
:: toiltmp5.bat: completing clean-up
if exist _clp_.tmp del _clp_.tmp
if exist toiltmp5.bat call toiltmp5.bat
if exist toiltmp1.bat del toiltmp1.bat
if exist toiltmp2.bat del toiltmp2.bat
if exist toiltmp3.bat del toiltmp3.bat
if exist toiltmp4.bat del toiltmp4.bat
if exist toiltmp5.bat del toiltmp5.bat